不带dhcp的boot的快捷固定ip【批处理命令-设置IP 子网掩码网关 dns】

xiaom***

本帖最后由 xiaomi1991 于 2024-1-15 17:09 编辑

作为一个混迹恩山论坛七年多的老油条，见过好多种boot引导。
其中也有好多种路由器的boot都不带dhcp功能。不带也无伤大雅，论坛大神能找到刷机方法，还把boot分享给我们我们已经很感激了。
不带dhcp的boot刷机就需要手动固定电脑ip和boot在同一网段，需要去网络设置那儿修改网络接口的ip 子网掩码网关等相对来说步骤稍微多了一点
因此经过一晚上的百度加上自己浅显的理解制作了一个批处理命令，用来快捷设置ip、子网掩码、网关和dns，供大家参考和交流。
我也是菜鸡，不喜勿喷，谢谢！！！

使用方法：
新建文本文档，把文件名改改xxx.bat。选中编辑文件，把如下代码区域内容复制到文件中，文件--另存为--编码改为：ANSI--选择要保存的路径--保存。如果不把编码方式改为ANSI，批处理中的汉字会显示乱码，影响观感。
此文件已在win10 教育版测试其他系统版本自行测试。也可以直接下载附件中的文件，直接使用即可。

批处理内容如下：

::设置关闭回显和变量延迟
@ECHO off & setlocal EnableDelayedExpansion
::设置标题文字
title 《Internet协议版本 4》设置批处理
::设置字体浅绿色
color 0A
echo ================================================================================
echo 欢迎使用《Internet协议版本 4》设置批处理命令
echo 制作者:xiaomi
echo ================================================================================
::提升当前批处理命令为管理员权限
NET FILE 1>NUL 2>NUL
if '%errorlevel%' == '0' (
echo 已提升该批处理命令为管理员权限
) else (
echo Requesting administrator rights...
powershell Start-Process -FilePath "%0" -Verb RunAs
exit /b
)
::默认值
:setDefault
::默认网络接口名称
set defaultInterfaceName=本地网络
::IP的默认分配方式 1:DHCP 2:static
set sourceIndex=1
::默认网关
set ipGateway=192.168.1.1
::默认子网掩码
set ipMask=255.255.255.0
::IP序号。ip是根据网关的前3位+这个ipNo组成,当前默认地址为192.168.1.100
set ipNo=100
::DNS的默认分配方式 1:DHCP 2:static 3:跳过设置
set DNSIndex=1
::默认首选DNS
set DNS1=114.114.114.114
::默认备用DNS
set DNS2=114.114.115.115
@echo.
::选择要修改网络配置的网络接口
:setInterfaceName
set defaultInterfaceIndex=65535
set tempInterfaceName=''
set index=0
for /f "tokens=3*" %%a in ('netsh interface show interface ^|more +2') do (
@echo !index!: %%b
set interfaceList[!index!]=%%b
set tempInterfaceName=%%b
if !tempInterfaceName! == !defaultInterfaceName! (
set defaultInterfaceIndex=!index!
)
set /A index+=1
)
if !defaultInterfaceIndex! == 65535 (
set /A interfaceIndex=!index!-1
) else (
set interfaceIndex=!defaultInterfaceIndex!
)
set /p interfaceIndex=请输入网络接口编号(默认值：!interfaceIndex!)：
if !interfaceIndex! geq !index! (
@echo.
echo 请输入网络接口编号有误，请重新输入！
goto setInterfaceName
)
set interfaceName=!interfaceList[%interfaceIndex%]!
echo 你的选择是：!interfaceName!
@echo.
::选择IP分配方式：DHCP或static
:setSourceName
echo IP地址获取方式：1:DHCP 2:static
set /p sourceIndex=请输入获取方式(默认值：!sourceIndex!)：
if !sourceIndex! == 1 (
set sourceName=dhcp
echo 你的选择是：DHCP
cmd /c netsh interface ip set address name="!interfaceName!" source=!sourceName! 1>nul 2>nul
goto setDNSSource
) else if !sourceIndex! == 2 (
set sourceName=static
echo 你的选择是：static
) else (
@echo.
echo 输入IP获取方式有误，请重新输入！
goto setSourceName
)
::static模式下IP的参数值
set /p ipGateway=请输入网关(默认值：!ipGateway!)：
echo 你的选择是：!ipGateway!
set /p ipMask=请输入子网掩码(默认值：!ipMask!)：
echo 你的选择是：!ipMask!
for /f "tokens=1,2,3,4 delims=." %%a in ("!ipGateway!") do (
set ipAddress= %%a.%%b.%%c.!ipNo!
)
set /p ipAddress=请输入IP地址(默认值：!ipAddress!)：
echo 你的选择是：!ipAddress!
cmd /c netsh interface ip set address name="!interfaceName!" source=!sourceName! address=!ipAddress! mask=!ipMask! gateway=!ipGateway! 1>nul 2>nul
@echo.
::选择DNS的分配模式：DHCP或static
:setDNSSource
echo DNS地址获取方式：1:DHCP 2:static 3:跳过
set /p DNSIndex=请输入获取方式(默认值：!DNSIndex!)：
::echo !DNSIndex!
::pause
if !DNSIndex! == 1 (
set DNSSourceName=dhcp
echo 你的选择是：!DNSSourceName!
cmd /c netsh interface ip set dnsservers name="!interfaceName!" source=dhcp 1>nul 2>nul
goto setExit
) else if !DNSIndex! == 2 (
set DNSSourceName=static
echo 你的选择是：!DNSSourceName!
goto setDNS
) else if !DNSIndex! == 3 (
echo 跳过设置DNS
goto setExit
) else (
@echo.
echo 输入IP获取方式有误，请重新输入！
goto setDNSSource
)
:setDNS
::static模式下DNS的参数值
set /p DNS1=请输入DNS1(默认值：!DNS1!)：
echo 你的选择是：!DNS1!
cmd /c netsh interface ip set dnsservers name="!interfaceName!" source=static address=!DNS1! register=primary validate=no 1>nul 2>nul
set /p DNS2=请输入DNS2(默认值：!DNS2!)：
echo 你的选择是：!DNS2!
cmd /c netsh interface ip add dnsservers name="!interfaceName!" address=!DNS2! index=2 validate=no 1>nul 2>nul
:setExit
@echo.
echo 查询当前配置：
@cmd /c netsh interface ip show config name="!interfaceName!"
pause

复制代码

amw***

谢谢分享！！！

ok9***

你真是一个小机灵鬼，为你点赞

scq***

感谢分享.............

账号		自动登录	找回密码
密码			立即注册

不带dhcp的boot的 快捷固定ip【批处理命令-设置IP 子网掩码 网关 dns】

本帖子中包含更多资源

不带dhcp的boot的快捷固定ip【批处理命令-设置IP 子网掩码网关 dns】